[From Nand to Tetris] Project 3 : Bit, Register, RAM8, RAM64, RAM512, RAM4K, RAM16K, PC

1) 1 - Bit Register

 /**
 * 1-bit register:
 * If load is asserted, the register's value is set to in;
 * Otherwise, the register maintains its current value:
 * if (load(t)) out(t+1) = in(t), else out(t+1) = out(t)
 */
 
CHIP Bit {
    IN in, load;
    OUT out;

    PARTS:
    Mux(a=gayout,b=in,sel=load,out=a);
    DFF(in=a,out=out,out=gayout);
}

---

2) 16- bit Register

/**
 * 16-bit register:
 * If load is asserted, the register's value is set to in;
 * Otherwise, the register maintains its current value:
 * if (load(t)) out(t+1) = int(t), else out(t+1) = out(t)
 */
CHIP Register {
    IN in[16], load;
    OUT out[16];

    PARTS:
    Bit(in=in[0],load=load,out=out[0]);
	Bit(in=in[1],load=load,out=out[1]);
	Bit(in=in[2],load=load,out=out[2]);
	Bit(in=in[3],load=load,out=out[3]);
	Bit(in=in[4],load=load,out=out[4]);
	Bit(in=in[5],load=load,out=out[5]);
	Bit(in=in[6],load=load,out=out[6]);
	Bit(in=in[7],load=load,out=out[7]);
	Bit(in=in[8],load=load,out=out[8]);
	Bit(in=in[9],load=load,out=out[9]);
	Bit(in=in[10],load=load,out=out[10]);
	Bit(in=in[11],load=load,out=out[11]);
	Bit(in=in[12],load=load,out=out[12]);
	Bit(in=in[13],load=load,out=out[13]);
	Bit(in=in[14],load=load,out=out[14]);
	Bit(in=in[15],load=load,out=out[15]);
}

---

3) RAM8

/**
 * Memory of eight 16-bit registers.
 * If load is asserted, the value of the register selected by
 * address is set to in; Otherwise, the value does not change.
 * The value of the selected register is emitted by out.
 */
CHIP RAM8 {
    IN in[16], load, address[3];
    OUT out[16];

    PARTS:
    DMux8Way(in=load, sel=address, a=r0, b=r1, c=r2, d=r3, e=r4, f=r5, g=r6, h=r7);
    Register(in=in, load=r0, out=r0Out);
    Register(in=in, load=r1, out=r1Out);
    Register(in=in, load=r2, out=r2Out);
    Register(in=in, load=r3, out=r3Out);
    Register(in=in, load=r4, out=r4Out);
    Register(in=in, load=r5, out=r5Out);
    Register(in=in, load=r6, out=r6Out);
    Register(in=in, load=r7, out=r7Out);
    Mux8Way16(a=r0Out, b=r1Out, c=r2Out, d=r3Out, e=r4Out, f=r5Out, g=r6Out, h=r7Out, sel=address, out=out);
}

---

4) RAM64

/**
 * Memory of 64 registers, each 16 bit-wide. Out holds the value
 * stored at the memory location specified by address. If load==1, then
 * the in value is loaded into the memory location specified by address
 * (the loaded value will be emitted to out from the next time step onward).
 */

CHIP RAM64 {
    IN in[16], load, address[6];
    OUT out[16];

    PARTS:
    DMux8Way(in=load, sel=address[0..2], a=r0, b=r1, c=r2, d=r3, e=r4, f=r5, g=r6, h=r7);
    RAM8(in=in, load=r0, address=address[3..5], out=r0Out);
    RAM8(in=in, load=r1, address=address[3..5], out=r1Out);
    RAM8(in=in, load=r2, address=address[3..5], out=r2Out);
    RAM8(in=in, load=r3, address=address[3..5], out=r3Out);
    RAM8(in=in, load=r4, address=address[3..5], out=r4Out);
    RAM8(in=in, load=r5, address=address[3..5], out=r5Out);
    RAM8(in=in, load=r6, address=address[3..5], out=r6Out);
    RAM8(in=in, load=r7, address=address[3..5], out=r7Out);
    Mux8Way16(a=r0Out, b=r1Out, c=r2Out, d=r3Out, e=r4Out, f=r5Out, g=r6Out, h=r7Out, sel=address[0..2], out=out);
}

---

5) RAM512

/**
 * Memory of 512 registers, each 16 bit-wide. Out holds the value
 * stored at the memory location specified by address. If load==1, then
 * the in value is loaded into the memory location specified by address
 * (the loaded value will be emitted to out from the next time step onward).
 */

CHIP RAM512 {
    IN in[16], load, address[9];
    OUT out[16];

    PARTS:
    DMux8Way(in=load, sel=address[0..2], a=r0, b=r1, c=r2, d=r3, e=r4, f=r5, g=r6, h=r7);
    RAM64(in=in, load=r0, address=address[3..8], out=r0out);
    RAM64(in=in, load=r1, address=address[3..8], out=r1out);
    RAM64(in=in, load=r2, address=address[3..8], out=r2out);
    RAM64(in=in, load=r3, address=address[3..8], out=r3out);
    RAM64(in=in, load=r4, address=address[3..8], out=r4out);
    RAM64(in=in, load=r5, address=address[3..8], out=r5out);
    RAM64(in=in, load=r6, address=address[3..8], out=r6out);
    RAM64(in=in, load=r7, address=address[3..8], out=r7out);
    Mux8Way16(a=r0out, b=r1out, c=r2out, d=r3out, e=r4out, f=r5out, g=r6out, h=r7out, sel=address[0..2], out=out);
}

---

6) RAM4K

/**
 * Memory of 4K registers, each 16 bit-wide. Out holds the value
 * stored at the memory location specified by address. If load==1, then
 * the in value is loaded into the memory location specified by address
 * (the loaded value will be emitted to out from the next time step onward).
 */

CHIP RAM4K {
    IN in[16], load, address[12];
    OUT out[16];

    PARTS:
    DMux8Way(in=load, sel=address[0..2], a=r0, b=r1, c=r2, d=r3, e=r4, f=r5, g=r6, h=r7);
    RAM512(in=in, load=r0, address=address[3..11], out=r0out);
    RAM512(in=in, load=r1, address=address[3..11], out=r1out);
    RAM512(in=in, load=r2, address=address[3..11], out=r2out);
    RAM512(in=in, load=r3, address=address[3..11], out=r3out);
    RAM512(in=in, load=r4, address=address[3..11], out=r4out);
    RAM512(in=in, load=r5, address=address[3..11], out=r5out);
    RAM512(in=in, load=r6, address=address[3..11], out=r6out);
    RAM512(in=in, load=r7, address=address[3..11], out=r7out);
    Mux8Way16(a=r0out, b=r1out, c=r2out, d=r3out, e=r4out, f=r5out, g=r6out, h=r7out, sel=address[0..2], out=out);
}

---

7) RAM16K

/**
 * Memory of 16K registers, each 16 bit-wide. Out holds the value
 * stored at the memory location specified by address. If load==1, then
 * the in value is loaded into the memory location specified by address
 * (the loaded value will be emitted to out from the next time step onward).
 */

CHIP RAM16K {
    IN in[16], load, address[14];
    OUT out[16];

    PARTS:
    DMux4Way(in=load, sel=address[0..1], a=r0, b=r1, c=r2, d=r3);
    RAM4K(in=in, load=r0, address=address[2..13], out=r0out);
    RAM4K(in=in, load=r1, address=address[2..13], out=r1out);
    RAM4K(in=in, load=r2, address=address[2..13], out=r2out);
    RAM4K(in=in, load=r3, address=address[2..13], out=r3out);
    Mux4Way16(a=r0out, b=r1out, c=r2out, d=r3out, sel=address[0..1], out=out);
}

---

8) PC

/**
 * A 16-bit counter with load and reset control bits.
 * if      (reset[t] == 1) out[t+1] = 0
 * else if (load[t] == 1)  out[t+1] = in[t]
 * else if (inc[t] == 1)   out[t+1] = out[t] + 1  (integer addition)
 * else                    out[t+1] = out[t]
 */

CHIP PC {
    IN in[16],load,inc,reset;
    OUT out[16];

    PARTS:
    Inc16(in=feedback, out=pc);
    Mux16(a=feedback, b=pc, sel=inc, out=w0);
    Mux16(a=w0, b=in, sel=load, out=w1);
    Mux16(a=w1, b=false, sel=reset, out=cout);
    Register(in=cout, load=true, out=out, out=feedback);
}